﻿ Newtontime.com - Gyroscopic Torque Explained

### The Gyroscopic Effect

#### by N. O. Williams

```10  CLS : REM Numerical integration program to calculate gyroscopic torque
15  REM       for a rotating ring which is simultaneously tilted.
20  REM       This is a check program which numerically integrates the combined trigonometric expression.
25  PRINT : PRINT: REM  Filename:-  Integral.txt
30  INPUT "INPUT NO. OF INTEGRATION ELEMENTS PER RING QUADRANT - USE A HIGHER NUMBER FOR GREATER ACCURACY"; Q
35  I = 4 * Q
40  K# = 3.1415926536#
45  PRINT
50  INPUT "INPUT TOTAL MASS OF RING IN KILOGRAMS"; M#
55  INPUT "RADIUS OF RING IN METRES"; R#
60  INPUT "INPUT SPIN SPEED OF RING IN R.P.M"; NS#
65  INPUT "INPUT TILT SPEED OF RING IN R.P.M"; NT#: PRINT
70  REM convert angular speeds to radians per second
75  WS# = 2 * K# * NS# / 60: WT# = 2 * K# * NT# / 60
80  REM ratio of tilt speed/spin speed"; C#
85  C# = NT# / NS#
90  REM ******************************************************************************
95  PRINT
100 REM Calculation for the First Two Quadrants
105 T1# = 0: P1# = 0
110 FOR J = 1 TO (I / 2)
115 REM Calculate angles (Radians) Theta & Phi, at far end of element
120 REM T2# = ((J) / (I / 2)) * K# / 180: P2# = ((J) * C# / (I / 2)) * K# / 180
125 T2# = J * 2 * K# / I: P2# = C# * T2#
130 REM First End of Element
135 CINC# = COS(T1#) * (2 * COS(T1#) * COS(P1#) - C# * SIN(T1#) * SIN(P1#))
140 REM Second End of Element
145 DINC# = COS(T2#) * (2 * COS(T2#) * COS(P2#) - C# * SIN(T2#) * SIN(P2#))
150 REM End values averaged to represent Centroid of Element
155 CSUM# = CSUM# + (2 * (CINC# + DINC#) / 2)
160 T1# = T2#:P1# = P2#
165 NEXT J
170 PRINT "TRIGONOMETRIC EXPRESSION NUMERICALLY INTEGRATED TORQUE VALUE = ";(M# * R# ^ 2 * WS# * WT#) * CSUM# / I:PRINT
175 PRINT "FORMULA-BASED COEFFICIENT FOR GYROSCOPIC TORQUE VALUE = "; M# * R# ^ 2 * WS# * WT# :  PRINT:PRINT
180 PRINT "RATIO OF NUMERICALLY INTEGRATED/FORMULA-BASED TORQUE VALUES = "; CSUM# / I: PRINT
185 END
```